home *** CD-ROM | disk | FTP | other *** search
/ No Fragments Archive 12: Textmags & Docs / nf_archive_12.iso / MAGS / SOURCES / ATARI_SRC.ZIP / atari source / DSHJ2 / FASTROT.S < prev    next >
Encoding:
Text File  |  2001-02-10  |  12.5 KB  |  712 lines
  1. *
  2. *
  3. *   Rotate 90 degrees clockwise a large rectangular page-size form in place
  4. *   where the DST form width is less than the SRC form
  5. *
  6. *   Programmer: Dave Staugas
  7. *         Date: 9-June-89
  8. *
  9. *
  10. *   Paper size data:                    Timings (secs):
  11. *                    Temp buf size:   5k  10k  20k  40k
  12. *     Port_width   Land_width   Rectangle excess  d2= 1    2    4    8
  13. *     ----------   ----------   ----------------
  14. *  Letter  300        398       98             56   35   25   20
  15. *  Legal   300        510       210            123   71   45   32
  16. *  A4       292        424       132             72   43   29   22
  17. *  B5       252        366       114             47   30   20   16
  18. *
  19. *
  20.     .globl    roto
  21.     .globl    recrot
  22. *
  23. *
  24. *   Entry:
  25. *
  26. *   a0   -> base address of landscape form to rotate
  27. *   a1   -> temp buffer allocated in multiples of (16 * DST form-width)
  28. *   d0.w =  SRC form-width in bytes (must be even)
  29. *   d1.w =  DST form-width in bytes (must be even)
  30. *   d2.w =  # of (16 * DST form-width) multiples that can be used in temp buffer
  31. *
  32. *   Exit:
  33. *
  34. *   all registers preserved, rectangular form is rotated in place
  35. *        90 degrees clockwise with new (DST) form-width
  36. *
  37. recrot:
  38.     movem.l    a0-a6/d0-d7,-(sp)
  39. *
  40. *  Test code
  41.     move.l    a0,lasrbaz
  42.     move.w    d0,lasrwid
  43.     move.w    d1,lasrht
  44. *  End test code
  45. *
  46. testpt0:
  47. *
  48. *  1st rotate largest chunk (a square) in place
  49. *
  50.     move.w    d1,d4        ;do a square rotate 1st
  51.     bsr    roto        ;rotate the biggest chunk in place
  52. *
  53. *  Now rotate-copy d2.w vertical columns of tiles to temp buffer
  54. *
  55.     move.l    a1,a5        ;save temp buf ptr in a5
  56.     lea    (a0,d1.w),a2    ;a2-> SRC top tile of column just rite of square
  57.     lea    -2(a1,d1.w),a3    ;a3-> DST top/rightmost tile of temp buf
  58. schlp:
  59.     move.w    d0,d7        ;d0 = SRC wrap
  60.     lsl.w    #4,d7        ;d7 = SRC tile wrap
  61. *
  62.     move.w    d1,d6        ;d1 = DST wrap
  63.     lsl.w    #4,d6        ;d6 = DST tile wrap
  64. *
  65.     move.l    a2,a4        ;save a2 for later
  66.     move.w    d1,d4        ;DST width
  67.     lsr.w    #1,d4
  68.     subq.w    #1,d4        ;d4 = # of tiles in column (-1)
  69.     subq.w    #1,d2        ;d2 = # of columns (-1)
  70. buflp0:
  71.     movem.l    a2-a3/d2/d4/d6,-(sp)
  72. buflp:
  73.     move.l    a2,a1
  74.     move.l    a3,a6
  75.     bsr    rot2tile
  76.     adda.w    d7,a2
  77.     subq.l    #2,a3    
  78.     dbra    d4,buflp
  79.  
  80.     movem.l    (sp)+,a2-a3/d2/d4/d6
  81.     addq.l    #2,a2
  82.     adda.w    d6,a3
  83.     dbra    d2,buflp0
  84. *
  85.     move.l    8(sp),d2    ;restore buffer size multiple
  86.     add.w    d2,d2        ;  in words
  87. *
  88. *   buffer is full, now scrunch the big form (decrease SRC width by d2*2 bytes)
  89. *
  90.     move.l    a4,a3        ;1st DST column just right of big square
  91.     lea    (a3,d2.w),a2    ;1st SRC column just right of copied columns
  92.     move.w    d1,d4
  93.     lsl.w    #3,d4        ;DST width *8 is # of rows
  94.     move.w    d4,d7
  95.     subq.w    #2,d7
  96. *
  97.     sub.w    d2,d0        ;new SRC width (it's shrinking)
  98.     move.w    d0,d4
  99.     lsr.w    #2,d4        ;get # of long words in SRC row
  100.     bcc.s    elong        ;br if integral # of longwords
  101. *
  102. *   else, do one short word 1st..
  103. *
  104. rwlp0:
  105.     move.w    d4,d5
  106.     move.w    (a2)+,(a3)+
  107.     bra.s    rwlp1i
  108. rwlp1:
  109.     move.l    (a2)+,(a3)+
  110. rwlp1i:
  111.     dbra    d5,rwlp1
  112.     adda.w    d2,a2
  113.     dbra    d7,rwlp0
  114.     bra.s    rwdone
  115. elong:    
  116.     move.w    d4,d5
  117.     bra.s    rwlp2i
  118. rwlp2:
  119.     move.l    (a2)+,(a3)+
  120. rwlp2i:
  121.     dbra    d5,rwlp2
  122.     adda.w    d2,a2
  123.     dbra    d7,elong
  124. rwdone:
  125.     move.w    d0,d7
  126.     sub.w    d1,d7
  127.     lsr.w    #1,d7
  128.     bra    rwlp5i            ;gotta get special case
  129. rwlp5:
  130.     move.w    (a2)+,(a3)+        ;copied for inner column difference
  131. rwlp5i:
  132.     dbra    d7,rwlp5
  133. *
  134. *
  135.     move.w    d1,d6        ;d1 = DST wrap
  136.     lsl.w    #4,d6        ;d6 = DST tile wrap
  137. *
  138. scrnchlp:
  139.     lea    (a0,d0.w),a2    ;a2-> SRC top tile column at far right 
  140.     lea    -2(a3,d1.w),a3    ;a3-> DST rightmost tile of space just freed
  141. *
  142. * 
  143.     move.w    d0,d7        ;d0 = SRC wrap
  144.     lsl.w    #4,d7        ;d7 = tile wrap
  145. *
  146.     sub.w    d2,d0        ;new SRC width (it's shrinking)
  147.     cmp.w    d1,d0        ;did we go too far?
  148.     bpl.s    .10        ;br if ok
  149. *
  150.     move.w    d1,d3
  151.     sub.w    d0,d3        ;d3 = # of word-columns not to do
  152.     sub.w    d3,d2        ;d2 = # of word-columns to do
  153.     add.w    d3,d0
  154.     lsr.w    #1,d3        ;d2 = # of columns not done this trip
  155.     mulu    d6,d3
  156.     add.l    d3,a3        ;adjust DST ptr
  157. .10:
  158.     add.w    d2,d0
  159.     suba.w    d2,a2        ;adjust SRC ptr
  160. *
  161.     move.l    a2,a4        ;save a2 for later
  162.     move.w    d1,d4        ;DST width
  163.     lsr.w    #1,d4
  164.     subq.w    #1,d4        ;d4 = # of tiles in column (-1)
  165.     move.w    d2,-(sp)
  166.     lsr.w    #1,d2
  167.     subq.w    #1,d2        ;d2 = # of columns (-1)
  168. bufloop0:
  169.     movem.l    a2-a3/d2/d4/d6,-(sp)
  170. bufloop:
  171.     move.l    a2,a1
  172.     move.l    a3,a6
  173.     bsr    rot2tile
  174.     adda.w    d7,a2
  175.     subq.l    #2,a3    
  176.     dbra    d4,bufloop
  177. *
  178.     movem.l    (sp)+,a2-a3/d2/d4/d6
  179.     addq.l    #2,a2
  180.     adda.w    d6,a3
  181.     dbra    d2,bufloop0
  182. *
  183.     move.w    (sp)+,d2
  184. *
  185. *   now scrunch the big form (decrease SRC width by d2 bytes)
  186. *
  187.     sub.w    d2,d0
  188.     move.l    a4,a3        ;1st DST to holding buffer
  189.     lea    (a3,d2.w),a2    ;1st SRC column just right of big square
  190.     move.w    d1,d4
  191.     lsl.w    #3,d4        ;DST width *8 is # of rows
  192.     move.w    d4,d7
  193.     subq.w    #2,d7
  194. *
  195.     move.w    d0,d4
  196.     lsr.w    #2,d4        ;get # of long words in SRC row
  197.     bcc.s    evnlong        ;br if integral # of longwords
  198. *
  199. *   else, do one short word 1st..
  200. *
  201. rowlp0:
  202.     move.w    d4,d5
  203.     move.w    (a2)+,(a3)+
  204.     bra.s    rowlp1i
  205. rowlp1:
  206.     move.l    (a2)+,(a3)+
  207. rowlp1i:
  208.     dbra    d5,rowlp1
  209.     adda.w    d2,a2
  210.     dbra    d7,rowlp0
  211.     bra.s    rowdone
  212. evnlong:    
  213.     move.w    d4,d5
  214.     bra.s    rowlp2i
  215. rowlp2:
  216.     move.l    (a2)+,(a3)+
  217. rowlp2i:
  218.     dbra    d5,rowlp2
  219.     adda.w    d2,a2
  220.     dbra    d7,evnlong
  221. rowdone:
  222.     cmp.w    d0,d1            ;have we become DST form-width?
  223.     bne    scrnchlp        ;iterate until we are DST
  224. *
  225. *   Now copy buffer to last freed area
  226. *
  227. *    a3-> DST tile area just freed
  228. *
  229.     move.l    a5,a2        ;get buffer copied back in
  230. *
  231.     lsl.w    #3,d0        ;DST wrap *8 is # of words in buffer
  232.     mulu    8+2(sp),d0
  233.     bra.s    bufini
  234. bufinlp:
  235.     move.w    (a2)+,(a3)+
  236. bufini:
  237.     dbra    d0,bufinlp
  238. *
  239. *   test code
  240.     move.w    lasrwid,d1
  241.     move.w    lasrht,d2
  242.     move.w    d2,lasrwid
  243.     move.w    d1,lasrht
  244. *
  245. *   end test
  246. *
  247. testpt1:
  248.     movem.l    (sp)+,a0-a6/d0-d7
  249.     rts
  250. *
  251. *   Rotate 90 degrees clockwise a large square page-size form in place
  252. *
  253. *   Programmer: Dave Staugas
  254. *         Date: 5-June-89
  255. *
  256. *   Entry:
  257. *
  258. *   a0   -> base address of square form to rotate
  259. *   d0.w =  form-width in bytes (must be even)
  260. *   d4.w =  # of bytes on a side of the square (also must be even)
  261. *
  262. *   Exit:
  263. *
  264. *  all regs preserved, square form is rotated in place 90 degrees clockwise
  265. *
  266. roto:
  267.     movem.l    a0-a6/d0-d7,-(sp)
  268.     move.w    d0,d7        ;copy form-width to d7
  269.     lsl.w    #4,d7        ;x16 for offset in form for 1 tile down
  270. *
  271.     lsr.w    #1,d4        ;d4 = # tiles on a side
  272. *
  273. *   a2 -> top/left tile address
  274. *
  275. *   d0 = form-wrap
  276. *   d4 = # of tiles on a side
  277. *   d7 = offset in form for 1 tile down
  278. *
  279. rotlp0:
  280.     move.l    a0,a2        ;a2 -> top/left tile
  281.     move.w    d4,d3
  282.     subq.w    #1,d3
  283.     mulu    d7,d3
  284.     lea    (a2,d3.l),a4    ;a4 -> bot/left tile
  285.     add.w    d4,d4
  286.     lea    -2(a2,d4.w),a3    ;a3 -> top/right tile
  287.     lea    -2(a4,d4.w),a5    ;a5 -> bot/right tile
  288.     lsr.w    #1,d4
  289. rotlp1:
  290.     move.l    a2,a1        ;top/left is SRC
  291.     moveq    #2,d1        ;DST form wrap (just 16 byte buffer)
  292.     lea    tilebuf,a6
  293.     bsr    rot2tile    ;rotate top/left to buffer
  294. *
  295.     move.l    a4,a1        ;bot/left is SRC
  296.     move.w    d0,d1        ;DST form wrap is same as SRC
  297.     move.l    a2,a6        ;top/left is DST
  298.     bsr    rot2tile    ;rotate bot/left to top/left tile
  299. *    
  300.     move.l    a5,a1        ;bot/right is SRC
  301.     move.l    a4,a6        ;bot/left is DST
  302.     bsr    rot2tile    ;rotate bot/right to bot/left tile
  303. *
  304.     move.l    a3,a1        ;top/right is SRC
  305.     move.l    a5,a6        ;bot/right is DST
  306.     bsr    rot2tile    ;rotate top/right to bot/right
  307. *
  308.     lea    tilebuf,a1
  309.     move.l    a3,a6
  310.     moveq    #15,d5
  311. coploop:
  312.     move.w    (a1)+,(a6)
  313.     adda.w    d0,a6
  314.     dbra    d5,coploop    ;copy rotated tile buffer to top/left
  315. *
  316.     adda.w    d7,a2        ;move top/left down 1 tile
  317.     suba.w    d7,a5        ;move bot/right up 1 tile
  318.     addq.l    #2,a4        ;move bot/left right 1 tile
  319.     subq.l    #2,a3        ;move top/right left 1 tile
  320.     cmp.l    a0,a3        ;does top/right equal base?
  321.     bne    rotlp1        ;iterate until it does
  322. *
  323.     lea    2(a0,d7.w),a0    ;now put base down 1 tile & left 1 tile
  324.     subq.l    #2,d4        ;next # of tiles on a side
  325.     beq.s    rotdone        ;br if none left
  326.     cmpi.w    #1,d4        ;check for odd case
  327.     bne    rotlp0
  328. *
  329.     move.l    a0,a1
  330.     move.l    a0,a6
  331.     bsr    rot2tile
  332. *
  333. rotdone:
  334.     movem.l    (sp)+,a0-a6/d0-d7
  335.     rts
  336. *
  337. *
  338. *
  339. *
  340. *    
  341. ******************************************
  342. *
  343. *   Rotate a 16x16 pixel tile clockwise 90 degrees and copy to another tile
  344. *
  345. *
  346. *   d0 = SRC form-wrap
  347. *   d1 = DST form-wrap
  348. *
  349. *   a1 -> top/left of SRC tile
  350. *   a6 -> top/left of DST tile
  351. *  
  352. rot2tile:
  353.     movem.l    a0/a2-a5/d0-d1/d4/d7,-(sp)
  354. *
  355. *  pack 16 words of tile into 4 data & 4 address registers..
  356. *
  357.     move.w    (a1),d2
  358.     adda.w    d0,a1
  359.     move.w    (a1),d3
  360.     adda.w    d0,a1
  361.     move.w    (a1),d4
  362.     adda.w    d0,a1
  363.     move.w    (a1),d5
  364.     adda.w    d0,a1
  365. *
  366.     swap    d2
  367.     swap    d3
  368.     swap    d4
  369.     swap    d5
  370. *
  371.     move.w    (a1),d2
  372.     adda.w    d0,a1
  373.     move.w    (a1),d3
  374.     adda.w    d0,a1
  375.     move.w    (a1),d4
  376.     adda.w    d0,a1
  377.     move.w    (a1),d5
  378.     adda.w    d0,a1
  379. *
  380.     exg    d2,a2
  381.     exg    d3,a3
  382.     exg    d4,a4
  383.     exg    d5,a5
  384. *
  385.     move.w    (a1),d2
  386.     adda.w    d0,a1
  387.     move.w    (a1),d3
  388.     adda.w    d0,a1
  389.     move.w    (a1),d4
  390.     adda.w    d0,a1
  391.     move.w    (a1),d5
  392.     adda.w    d0,a1
  393. *
  394.     swap    d2
  395.     swap    d3
  396.     swap    d4
  397.     swap    d5
  398. *
  399.     move.w    (a1),d2
  400.     adda.w    d0,a1
  401.     move.w    (a1),d3
  402.     adda.w    d0,a1
  403.     move.w    (a1),d4
  404.     adda.w    d0,a1
  405.     move.w    (a1),d5
  406. *
  407. *   Got all 16 words of tile in registers, now rotate..
  408. *
  409.     moveq    #3,d0        ;iterate 4 times
  410. rotlp2:
  411.     swap    d1        ;DST form-width to high word
  412.     swap    d0        ;get d0.w ready to receive bits
  413.     add.w    d5,d5
  414.     addx.w    d1,d1
  415.     add.w    d5,d5
  416.     addx.w    d0,d0
  417.     add.w    d5,d5
  418.     addx.w    d6,d6
  419.     add.w    d5,d5
  420.     addx.w    d7,d7
  421.  
  422.     add.w    d4,d4
  423.     addx.w    d1,d1
  424.     add.w    d4,d4
  425.     addx.w    d0,d0
  426.     add.w    d4,d4
  427.     addx.w    d6,d6
  428.     add.w    d4,d4
  429.     addx.w    d7,d7
  430.  
  431.     add.w    d3,d3
  432.     addx.w    d1,d1
  433.     add.w    d3,d3
  434.     addx.w    d0,d0
  435.     add.w    d3,d3
  436.     addx.w    d6,d6
  437.     add.w    d3,d3
  438.     addx.w    d7,d7
  439.  
  440.     add.w    d2,d2
  441.     addx.w    d1,d1
  442.     add.w    d2,d2
  443.     addx.w    d0,d0
  444.     add.w    d2,d2
  445.     addx.w    d6,d6
  446.     add.w    d2,d2
  447.     addx.w    d7,d7
  448. *
  449.     swap    d2
  450.     swap    d3
  451.     swap    d4
  452.     swap    d5
  453. *
  454.     add.w    d5,d5
  455.     addx.w    d1,d1
  456.     add.w    d5,d5
  457.     addx.w    d0,d0
  458.     add.w    d5,d5
  459.     addx.w    d6,d6
  460.     add.w    d5,d5
  461.     addx.w    d7,d7
  462.  
  463.     add.w    d4,d4
  464.     addx.w    d1,d1
  465.     add.w    d4,d4
  466.     addx.w    d0,d0
  467.     add.w    d4,d4
  468.     addx.w    d6,d6
  469.     add.w    d4,d4
  470.     addx.w    d7,d7
  471.  
  472.     add.w    d3,d3
  473.     addx.w    d1,d1
  474.     add.w    d3,d3
  475.     addx.w    d0,d0
  476.     add.w    d3,d3
  477.     addx.w    d6,d6
  478.     add.w    d3,d3
  479.     addx.w    d7,d7
  480.  
  481.     add.w    d2,d2
  482.     addx.w    d1,d1
  483.     add.w    d2,d2
  484.     addx.w    d0,d0
  485.     add.w    d2,d2
  486.     addx.w    d6,d6
  487.     add.w    d2,d2
  488.     addx.w    d7,d7
  489. *
  490.     swap    d2
  491.     swap    d3
  492.     swap    d4
  493.     swap    d5
  494. *
  495.     exg    d2,a2
  496.     exg    d3,a3
  497.     exg    d4,a4
  498.     exg    d5,a5
  499. *
  500. *
  501.     add.w    d5,d5
  502.     addx.w    d1,d1
  503.     add.w    d5,d5
  504.     addx.w    d0,d0
  505.     add.w    d5,d5
  506.     addx.w    d6,d6
  507.     add.w    d5,d5
  508.     addx.w    d7,d7
  509.  
  510.     add.w    d4,d4
  511.     addx.w    d1,d1
  512.     add.w    d4,d4
  513.     addx.w    d0,d0
  514.     add.w    d4,d4
  515.     addx.w    d6,d6
  516.     add.w    d4,d4
  517.     addx.w    d7,d7
  518.  
  519.     add.w    d3,d3
  520.     addx.w    d1,d1
  521.     add.w    d3,d3
  522.     addx.w    d0,d0
  523.     add.w    d3,d3
  524.     addx.w    d6,d6
  525.     add.w    d3,d3
  526.     addx.w    d7,d7
  527.  
  528.     add.w    d2,d2
  529.     addx.w    d1,d1
  530.     add.w    d2,d2
  531.     addx.w    d0,d0
  532.     add.w    d2,d2
  533.     addx.w    d6,d6
  534.     add.w    d2,d2
  535.     addx.w    d7,d7
  536. *
  537. *
  538.     swap    d2
  539.     swap    d3
  540.     swap    d4
  541.     swap    d5
  542. *
  543.  
  544.     add.w    d5,d5
  545.     addx.w    d1,d1
  546.     add.w    d5,d5
  547.     addx.w    d0,d0
  548.     add.w    d5,d5
  549.     addx.w    d6,d6
  550.     add.w    d5,d5
  551.     addx.w    d7,d7
  552.  
  553.     add.w    d4,d4
  554.     addx.w    d1,d1
  555.     add.w    d4,d4
  556.     addx.w    d0,d0
  557.     add.w    d4,d4
  558.     addx.w    d6,d6
  559.     add.w    d4,d4
  560.     addx.w    d7,d7
  561.  
  562.     add.w    d3,d3
  563.     addx.w    d1,d1
  564.     add.w    d3,d3
  565.     addx.w    d0,d0
  566.     add.w    d3,d3
  567.     addx.w    d6,d6
  568.     add.w    d3,d3
  569.     addx.w    d7,d7
  570.  
  571.     add.w    d2,d2
  572.     addx.w    d1,d1
  573.     add.w    d2,d2
  574.     addx.w    d0,d0
  575.     add.w    d2,d2
  576.     addx.w    d6,d6
  577.     add.w    d2,d2
  578.     addx.w    d7,d7
  579. *
  580.     swap    d2
  581.     swap    d3
  582.     swap    d4
  583.     swap    d5
  584. *
  585.     exg    d2,a2
  586.     exg    d3,a3
  587.     exg    d4,a4
  588.     exg    d5,a5
  589. *
  590.     move.w    d1,(a6)
  591.     swap    d1        ;get DST form-width
  592.     adda.w    d1,a6
  593.     move.w    d0,(a6)
  594.     swap    d0        ;get loop count
  595.     adda.w    d1,a6
  596.     move.w    d6,(a6)
  597.     adda.w    d1,a6
  598.     move.w    d7,(a6)
  599.     adda.w    d1,a6
  600. *
  601.     dbra    d0,rotlp2    ;do all 16
  602. *
  603.     movem.l    (sp)+,a0/a2-a5/d0-d1/d4/d7
  604.     rts
  605. *
  606. *
  607. *
  608. *
  609. *  test code
  610. *
  611. view:
  612.     movem.l    a0-a6/d0-d7,-(sp)
  613.     moveq    #0,d1            ;horz
  614.     moveq    #0,d2            ;vert
  615. view0:
  616.     move.l    lasrbaz,a0
  617.     move.w    d2,d0
  618.     mulu    lasrwid,d0
  619.     add.l    d0,a0
  620.     add.l    d1,a0
  621.     lea    $c00000,a1
  622.     move.w    lasrwid,d0
  623.     sub.w    #160,d0
  624.  
  625.     move.w    lasrht,d4
  626.     lsl.w    #3,d4
  627.     move.w    #960,d5
  628.     add.w    d2,d5
  629.     cmp.w    d5,d4
  630.     bcc.s    doview
  631.     sub.w    d4,d5
  632.     move.w    #960,d4
  633.     sub.w    d5,d4
  634.     bra.s    view1i
  635. doview:
  636.     move.w    #960,d4
  637.     moveq    #0,d5
  638.     bra.s    view1i
  639. view1:
  640.     move.w    #79,d3
  641. view2:
  642.     move.w    (a0)+,(a1)+
  643.     dbra    d3,view2
  644.     adda.w    d0,a0
  645. view1i:
  646.     dbra    d4,view1
  647. *
  648.     subq.w    #1,d5
  649.     bmi.s    viewdon
  650.     move.w    #79,d3
  651. view3:
  652.     move.w    #-1,(a1)+
  653.     dbra    d3,view3
  654.     bra.s    view4i
  655. view4:
  656.     move.w    #79,d3
  657. view5:
  658.     clr.w    (a1)+
  659.     dbra    d3,view5
  660. view4i:
  661.     dbra    d5,view4
  662. viewdon:
  663. *
  664.     movem.l    d1-d2,-(sp)
  665.     move.w    #2,-(sp)    
  666.     move.w    #2,-(sp)    
  667.     trap    #13
  668.     addq.l    #4,sp
  669.     movem.l    (sp)+,d1-d2
  670.     tst.w    d0
  671.     bne.s    exit
  672.     swap    d0
  673.     cmpi.b    #$4d,d0        ;rite
  674.     bne.s    .10
  675.     add.w    #80,d1
  676.     bra    view0
  677. .10:
  678.     cmpi.b    #$4b,d0        ;left
  679.     bne.s    .20
  680.     sub.w    #80,d1
  681.     bpl    view0
  682.     moveq    #0,d1
  683.     bra    view0
  684. .20:
  685.     cmpi.b    #$50,d0        ;down
  686.     bne.s    .30
  687.     add.w    #480,d2
  688.     bra    view0
  689. .30:
  690.     cmpi.b    #$48,d0        ;up
  691.     bne.s    exit
  692.     sub.w    #480,d2
  693.     bpl    view0
  694.     moveq    #0,d2
  695.     bra    view0
  696. *
  697. exit:
  698.     movem.l    (sp)+,a0-a6/d0-d7
  699.     rts
  700. *
  701. lasrbaz:
  702.     .dc.l    $c00000
  703. lasrwid:
  704.     .dc.w    160
  705. lasrht:
  706.     .dc.w    50
  707. *
  708. *
  709.     .bss
  710. tilebuf:
  711.     .ds.w    16
  712.